Ticket #10983: trac_10983.patch

new file sage/tests/french_book/calculus.py

@@ +1 @@
+r"""
+sage: var ('a,x') ; y = cos(x+a)*(x+1) ; y
+(a, x)
+(x + 1)*cos(a + x)
+sage: var ('a,x') ; y = cos(x+a)*(x+1) ; y
+(a, x)
+(x + 1)*cos(a + x)
+sage: y.subs(a=-x) ; y.subs(x=pi/2,a=pi/3) ; y.subs(x=0.5,a=2.3)
+x + 1
+-1/4*(pi + 2)*sqrt(3)
+-1.41333351100299
+sage: y(a=-x) ; y(x=pi/2,a=pi/3) ; y(x=0.5,a=2.3)
+x + 1
+-1/4*(pi + 2)*sqrt(3)
+-1.41333351100299
+sage: var('x,y,z') ; q = x*y+y*z+z*x
+(x, y, z)
+sage: bool (q(x=y,y=z,z=x)==q), bool(q(z=y)(y=x) == 3*x^2)
+(True, True)
+sage: var('y z'); f = x^3+y^2+z; f.subs_expr(x^3==y^2, z==1)
+(y, z)
+2*y^2 + 1
+sage: f(x)=(2*x+1)^3 ; f(-3)
+  -125
+sage: f(x).expand()
+8*x^3 + 12*x^2 + 6*x + 1
+sage: var('y'); u = sin(x) + x*cos(y)
+y
+sage: v = u.function(x, y); v
+(x, y) |--> x*cos(y) + sin(x)
+sage: w(x, y) = u; w
+(x, y) |--> x*cos(y) + sin(x)
+sage: (x^x/x).simplify()
+x^(x - 1)
+sage: f = (e^x-1)/(1+e^(x/2)); f.simplify_exp()
+e^(1/2*x) - 1
+sage: f = cos(x)^6 + sin(x)^6 + 3 * sin(x)^2 * cos(x)^2
+sage: f.simplify_trig()
+1
+sage: f = cos(x)^6; f.reduce_trig()
+15/32*cos(2*x) + 3/16*cos(4*x) + 1/32*cos(6*x) + 5/16
+sage: f = sin(5 * x); f.expand_trig()
+sin(x)^5 - 10*sin(x)^3*cos(x)^2 + 5*sin(x)*cos(x)^4
+sage: n = var('n'); f = factorial(n+1)/factorial(n)
+sage: f.simplify_factorial()
+n + 1
+sage: f = sqrt(x^2); f.simplify_radical()
+abs(x)
+sage: f = log(x*y); f.simplify_radical()
+log(x) + log(y)
+sage: assume(x > 0); bool(sqrt(x^2) == x)
+True
+sage: forget(x > 0); bool(sqrt(x^2) == x)
+False
+sage: var('n'); assume(n, 'integer'); sin(n*pi).simplify()
+n
+0
+sage: z, phi = var('z, phi')
+sage: solve(z**2 -2 / cos(phi) * z + 5 / cos(phi) ** 2 - 4, z)
+[z == -(2*sqrt(cos(phi)^2 - 1) - 1)/cos(phi), z == (2*sqrt(cos(phi)^2 - 1) + 1)/cos(phi)]
+sage: var('y'); solve(y^6==y, y)
+y
+[y == e^(2/5*I*pi), y == e^(4/5*I*pi), y == e^(-4/5*I*pi), y == e^(-2/5*I*pi), y == 1, y == 0]
+sage: solve(x^2-1, x, solution_dict=True)
+[{x: -1}, {x: 1}]
+sage: solve([x+y == 3, 2*x+2*y == 6],x,y)
+[[x == -r1 + 3, y == r1]]
+sage: solve([cos(x)*sin(x) == 1/2, x+y == 0], x, y)
+[[x == 1/4*pi + pi*z30, y == -1/4*pi - pi*z30]]
+sage: solve(x^2+x-1>0,x)
+[[x < -1/2*sqrt(5) - 1/2], [x > 1/2*sqrt(5) - 1/2]]
+sage: x, y, z = var('x, y, z')
+sage: solve([x^2 * y * z == 18, x * y^3 * z == 24,\
+             x * y * z^4 == 6], x, y, z)
+[[x == 3, y == 2, z == 1], [x == (1.33721506733 - 2.68548987407*I), y == (-1.70043427146 + 1.05286432575*I), z == (0.932472229404 - 0.361241666187*I)], [x == (1.33721506733 + 2.68548987407*I), y == (-1.70043427146 - 1.05286432575*I), z == (0.932472229404 + 0.361241666187*I)], [x == (-2.55065140719 - 1.57929648863*I), y == (-0.547325980144 + 1.92365128635*I), z == (-0.982973099684 - 0.183749517817*I)], [x == (-2.55065140719 + 1.57929648863*I), y == (-0.547325980144 - 1.92365128635*I), z == (-0.982973099684 + 0.183749517817*I)], [x == (0.27680507839 - 2.98720252889*I), y == (1.47801783444 - 1.34739128729*I), z == (-0.85021713573 - 0.526432162877*I)], [x == (0.27680507839 + 2.98720252889*I), y == (1.47801783444 + 1.34739128729*I), z == (-0.85021713573 + 0.526432162877*I)], [x == (-0.820988970216 + 2.88547692952*I), y == (-1.20526927276 - 1.59603445456*I), z == (0.0922683594633 - 0.995734176295*I)], [x == (-0.820988970216 - 2.88547692952*I), y == (-1.20526927276 + 1.59603445456*I), z == (0.0922683594633 + 0.995734176295*I)], [x == (-1.80790390914 - 2.39405168184*I), y == (0.891476711553 - 1.79032658271*I), z == (0.739008917221 - 0.673695643647*I)], [x == (-1.80790390914 + 2.39405168184*I), y == (0.891476711553 + 1.79032658271*I), z == (0.739008917221 + 0.673695643647*I)], [x == (2.21702675166 + 2.02108693094*I), y == (1.86494445881 + 0.722483332374*I), z == (-0.273662990072 - 0.961825643173*I)], [x == (2.21702675166 - 2.02108693094*I), y == (1.86494445881 - 0.722483332374*I), z == (-0.273662990072 + 0.961825643173*I)], [x == (2.79741668821 - 1.08372499856*I), y == (-1.96594619937 + 0.367499035633*I), z == (-0.602634636379 - 0.79801722728*I)], [x == (2.79741668821 + 1.08372499856*I), y == (-1.96594619937 - 0.367499035633*I), z == (-0.602634636379 + 0.79801722728*I)], [x == (-2.94891929905 + 0.55124855345*I), y == (0.184536718927 + 1.99146835259*I), z == (0.445738355777 - 0.895163291355*I)], [x == (-2.94891929905 - 0.55124855345*I), y == (0.184536718927 - 1.99146835259*I), z == (0.445738355777 + 0.895163291355*I)]]
+sage: expr = sin(x) + sin(2 * x) + sin(3 * x)
+sage: solve(expr, x)
+[sin(3*x) == -sin(2*x) - sin(x)]
+sage: find_root(expr, 0.1, pi)
+2.0943951023931957
+sage: f = expr.simplify_trig(); f
+2*(2*cos(x)^2 + cos(x))*sin(x)
+sage: solve(f, x)
+[x == 0, x == 2/3*pi, x == 1/2*pi]
+sage: (x^3+2*x+1).roots(x)
+[(-1/2*(I*sqrt(3) + 1)*(1/18*sqrt(3)*sqrt(59) - 1/2)^(1/3) - 1/3*(I*sqrt(3) - 1)/(1/18*sqrt(3)*sqrt(59) - 1/2)^(1/3), 1), (-1/2*(-I*sqrt(3) + 1)*(1/18*sqrt(3)*sqrt(59) - 1/2)^(1/3) - 1/3*(-I*sqrt(3) - 1)/(1/18*sqrt(3)*sqrt(59) - 1/2)^(1/3), 1), ((1/18*sqrt(3)*sqrt(59) - 1/2)^(1/3) - 2/3/(1/18*sqrt(3)*sqrt(59) - 1/2)^(1/3), 1)]
+sage: (x^3+2*x+1).roots(x, ring=RR)
+ [(-0.453397651516404, 1)]
+sage: (x^3+2*x+1).roots(x, ring=CC)
+ [(-0.453397651516404, 1), (0.226698825758202 - 1.46771150871022*I, 1), (0.226698825758202 + 1.46771150871022*I, 1)]
+sage: var('k n'); sum(k, k, 1, n).factor()
+ (k, n)
+ 1/2*(n + 1)*n
+sage: var('n y'); sum(binomial(n,k) * x^k * y^(n-k), k, 0, n)
+ (n, y)
+ (x + y)^n
+sage: var('k n'); sum(binomial(n,k), k, 0, n),\
+                  sum(k * binomial(n, k), k, 0, n),\
+                  sum((-1)^k*binomial(n,k), k, 0, n)
+(k, n)
+(2^n, n*2^(n - 1), 0)
+sage: var('a q'); sum(a*q^k, k, 0, n)
+(a, q)
+(a*q^(n + 1) - a)/(q - 1)
+sage: assume(abs(q) < 1)
+sage: sum(a*q^k, k, 0, infinity)
+ -a/(q - 1)
+sage: limit((x**(1/3) -2) / ((x + 19)**(1/3) - 3), x = 8)
+9/4
+sage: f(x) = (cos(pi/4-x)-tan(x))/(1-sin(pi/4 + x))
+sage: limit(f(x), x = pi/4, dir='minus')
++Infinity
+sage: limit(f(x), x = pi/4, dir='plus')
+-Infinity
+sage: u(n) = n^100 / 100.^n
+sage: u(1);u(2);u(3);u(4);u(5);u(6);u(7);u(8);u(9);u(10)
+0.0100000000000000
+1.26765060022823e26
+5.15377520732011e41
+1.60693804425899e52
+7.88860905221012e59
+6.53318623500071e65
+3.23447650962476e70
+2.03703597633449e74
+2.65613988875875e77
+1.00000000000000e80
+sage: plot(u(x), x, 1, 40)
+sage: v(x) = diff(u(x), x); sol = solve(v(x) == 0, x); sol
+[x == 0, x == (268850/12381)]
+sage: sol[1].rhs().n().floor()
+21
+sage: limit(u(n), n=infinity)
+0
+sage: n0 = find_root(u(n) - 1e-8 == 0, 22, 1000); n0
+105.07496210187252
+sage: taylor((1+arctan(x))**(1/x), x, 0, 3)
+1/16*x^3*e + 1/8*x^2*e - 1/2*x*e + e
+sage: (ln(2* sin(x))).series(x==pi/6, 3)
+(sqrt(3))*(-1/6*pi + x) + (-2)*(-1/6*pi + x)^2 + Order(-1/216*(pi - 6*x)^3)
+sage: (ln(2* sin(x))).series(x==pi/6, 3).truncate()
+-1/18*(pi - 6*x)^2 - 1/6*(pi - 6*x)*sqrt(3)
+sage: taylor((x**3+x)**(1/3) - (x**3-x)**(1/3), x, infinity, 2)
+2/3/x
+sage: tan(4*arctan(1/5)).simplify_trig()
+120/119
+sage: tan(pi/4+arctan(1/239)).simplify_trig()
+120/119
+sage: f = arctan(x).series(x, 10); f
+1*x + (-1/3)*x^3 + 1/5*x^5 + (-1/7)*x^7 + 1/9*x^9 + Order(x^10)
+sage: (16*f.subs(x==1/5) - 4*f.subs(x==1/239)).n(); pi.n()
+3.14159268240440
+3.14159265358979
+sage: var('k'); sum(1/k^2, k, 1, infinity),\
+                sum(1/k^4, k, 1, infinity),\
+                sum(1/k^5, k, 1, infinity)
+k
+(1/6*pi^2, 1/90*pi^4, zeta(5))
+sage: s = 2*sqrt(2)/9801*(sum((factorial(4*k))*(1103+26390*k)\
+     /((factorial(k)) ^ 4 * 396 ^ (4 * k)) for k in (0..11)))
+sage: (1 / s).n(digits=100); pi.n(digits=100)
+3.141592653589793238462643383279502884197169399375105820974944592307816406286208998628034825342121432
+3.141592653589793238462643383279502884197169399375105820974944592307816406286208998628034825342117068
+sage: print "%e" % (pi - 1 / s).n(digits=100)
+-4.364154e-96
+sage: var('n'); u = sin(pi*(sqrt(4*n^2+1)-2*n))
+n
+sage: taylor(u, n, infinity, 3)
+1/4*pi/n - 1/384*(6*pi + pi^3)/n^3
+sage: diff(sin(x^2), x)
+2*x*cos(x^2)
+sage: function('f',x); function('g',x); diff(f(g(x)), x)
+f(x)
+g(x)
+D[0](f)(g(x))*D[0](g)(x)
+sage: diff(ln(f(x)), x)
+D[0](f)(x)/f(x)
+sage: f(x,y) = x*y + sin(x^2) + e^(-x); derivative(f, x)
+(x, y) |--> 2*x*cos(x^2) + y - e^(-x)
+sage: derivative(f, y)
+(x, y) |--> x
+sage: var('x y'); f = ln(x**2+y**2) / 2
+(x, y)
+sage: delta = diff(f,x,2)+diff(f,y,2)
+sage: delta.simplify_full()
+0
+sage: sin(x).integral(x, 0, pi/2)
+1
+sage: integrate(1/(1+x^2), x)
+arctan(x)
+sage: integrate(1/(1+x^2), x, -infinity, infinity)
+pi
+sage: integrate(exp(-x**2), x, 0, infinity)
+1/2*sqrt(pi)
+sage: u = var('u'); f = x * cos(u) / (u^2 + x^2)
+sage: assume(x>0); f.integrate(u, 0, infinity)
+1/2*pi*e^(-x)
+sage: forget(); assume(x<0); f.integrate(u, 0, infinity)
+-1/2*pi*e^x
+sage: integral_numerical(sin(x)/x, 0, 1)
+(0.946083070367182..., 1.050363207929708...e-14)
+sage: g = integrate(exp(-x**2), x, 0, infinity); g, g.n()
+(1/2*sqrt(pi), 0.886226925452...)
+sage: approx = integral_numerical(exp(-x**2), 0, infinity)
+sage: approx[0]
+0.88622692545275...
+sage: A = matrix(QQ,[[1,2],[3,4]]); A
+[1 2]
+[3 4]
+sage: A = matrix(QQ, [[2, 4, 3],[-4,-6,-3],[3,3,1]])
+sage: A.characteristic_polynomial()
+x^3 + 3*x^2 - 4
+sage: A.eigenvalues()
+[1, -2, -2]
+sage: A.minimal_polynomial().factor()
+(x - 1) * (x + 2)^2
+sage: A.eigenvectors_right()
+[(1, [
+(1, -1, 1)
+], 1), (-2, [
+(1, -1, 0)
+], 2)]
+sage: A.jordan_form(transformation=True)
+(
+[ 1| 0  0]
+[--+-----]  [ 1  1  1]
+[ 0|-2  1]  [-1 -1  0]
+[ 0| 0 -2], [ 1  0 -1]
+)
+sage: A = matrix(QQ, [[1,-1/2],[-1/2,-1]])
+sage: A.minimal_polynomial()
+x^2 - 5/4
+sage: R = QQ[sqrt(5)]
+sage: A = A.change_ring(R)
+sage: A.jordan_form(transformation=True, subdivide=False)
+(
+[ 1/2*sqrt5          0]  [         1          1]
+[         0 -1/2*sqrt5], [-sqrt5 + 2  sqrt5 + 2]
+)
+sage: K.<sqrt2> = NumberField(x^2 - 2)
+sage: L.<sqrt3> = K.extension(x^2 - 3)
+sage: A = matrix(L, [[2, sqrt2*sqrt3, sqrt2], [sqrt2*sqrt3, 3, sqrt3], [sqrt2, sqrt3, 1]])
+sage: A.jordan_form(transformation=True)
+(
+[6|0|0]
+[-+-+-]
+[0|0|0]  [              1               1               0]
+[-+-+-]  [1/2*sqrt2*sqrt3               0               1]
+[0|0|0], [      1/2*sqrt2          -sqrt2          -sqrt3]
+)
+
+"""

new file sage/tests/french_book/graphique_1.py

@@ +1 @@
+r"""
+sage: g = plot(x * sin(1/x), x, -2, 2, plot_points=500)
+sage: def p(x, n): return(taylor(sin(x), x, 0, n))
+sage: xmax = 15 ; n = 15
+sage: g = plot(sin(x), x, -xmax, xmax)
+sage: for d in range(n):
+...     g += plot(p(x, 2 * d + 1), x, -xmax, xmax,\
+...       color=(1.7*d/(2*n), 1.5*d/(2*n), 1-3*d/(4*n)))
+sage: # g.show(ymin=-2, ymax=2)
+sage: a = animate([[sin(x), taylor(sin(x), x, 0, 2*k+1)]\
+...          for k in range(0, 14)], xmin=-14, xmax=14,\
+...          ymin=-3, ymax=3, figsize=[8, 4])
+sage: # a.show()
+sage: f2(x) = 1; f1(x) = -1
+sage: f = Piecewise([[(-pi,0),f1],[(0,pi),f2]])
+sage: S = f.fourier_series_partial_sum(20,pi); S
+4/3*sin(3*x)/pi + 4/5*sin(5*x)/pi + 4/7*sin(7*x)/pi + 4/9*sin(9*x)/pi + 4/11*sin(11*x)/pi + 4/13*sin(13*x)/pi + 4/15*sin(15*x)/pi + 4/17*sin(17*x)/pi + 4/19*sin(19*x)/pi + 4*sin(x)/pi
+sage: g = plot(S, x, -8, 8, color='blue')
+sage: scie(x) = x - 2 * pi * floor((x + pi) / (2 * pi))
+sage: g += plot(scie(x) / abs(scie(x)), x, -8, 8, color='red')
+sage: t = var('t')
+sage: x = cos(t) + cos(7*t)/2 + sin(17*t)/3
+sage: y = sin(t) + sin(7*t)/2 + cos(17*t)/3
+sage: g = parametric_plot( (x, y), (t, 0, 2*pi))
+sage: # g.show(aspect_ratio=1)
+sage: t = var('t'); e, n = 2, 20/19
+sage: g1 = polar_plot(1+e*cos(n*t),(t,0,n*38*pi),plot_points=5000)
+sage: e, n = 1/3, 20/19
+sage: g2 = polar_plot(1+e*cos(n*t),(t,0,n*38*pi),plot_points=5000)
+sage: # g1.show(aspect_ratio=1); g2.show(aspect_ratio=1)
+sage: z = var('z'); g1 = complex_plot(abs(cos(z^4)) - 1,\
+...             (-3, 3), (-3, 3), plot_points=400)
+sage: f = lambda x, y : (abs(cos((x + I * y) ** 4)) - 1)
+sage: g2 = implicit_plot(f, (-3, 3), (-3, 3), plot_points=400)
+sage: # g1.show(aspect_ratio=1); g2.show(aspect_ratio=1)
+sage: f(z) = z^5 + z - 1 + 1/z
+sage: g = complex_plot(f,\
+...      (-3, 3), (-3, 3))
+
+"""

new file sage/tests/french_book/graphique_2.py

@@ +1 @@
+r"""
+sage: g = bar_chart([randrange(15) for i in range(20)], color='red')
+sage: g = bar_chart([x^2 for x in range(1,20)], width=0.2)
+sage: liste = [10 + floor(10*sin(i)) for i in range(100)]
+sage: g = bar_chart(liste)
+sage: g = finance.TimeSeries(liste).plot_histogram(bins=20)
+sage: from random import *
+sage: n, l, x, y = 10000, 1, 0, 0; p = [[0, 0]]
+sage: for k in range(n):
+...    theta = (2 * pi * random()).n(digits=5)
+...    x, y = x + l * cos(theta), y + l * sin(theta)
+...    p.append([x, y])
+sage: g1 = line([p[n], [0, 0]], color='red', thickness=2)
+sage: g1 += line(p, thickness=.4); # g1.show(aspect_ratio=1)
+sage: length = 200; n = var('n')
+sage: u(n) = n * sqrt(2)
+sage: z(n) = exp(2 * I * pi * u(n))
+sage: vertices = [CC(0, 0)]
+sage: for n in range(1, length):
+...    vertices.append(vertices[n - 1] + CC(z(n)))
+sage: g = line(vertices); # g.show(aspect_ratio=1)
+sage: x = var('x'); y = function('y',x)
+sage: DE = x*diff(y, x) == 2*y + x^3
+sage: desolve(DE, [y,x])
+(c + x)*x^2
+sage: sol = []
+sage: for i in srange(-2, 2, 0.2):
+...    sol.append(desolve(DE, [y, x], ics=[1, i]))
+...    sol.append(desolve(DE, [y, x], ics=[-1, i]))
+sage: g = plot(sol, x, -2, 2)
+sage: y = var('y')
+sage: g += plot_vector_field((x, 2*y+x^3), (x, -2, 2), (y, -1, 1))
+sage: # g.show(ymin=-1, ymax=1)
+sage: # debut variante
+sage: x = var('x'); y = function('y',x)
+sage: DE = x*diff(y, x) == 2*y + x^3
+sage: g = Graphics()
+sage: for i in srange(-1, 1, 0.1):
+...       g += line(desolve_rk4(DE, y, ics=[1, i],\
+...                         step=0.05, end_points=[0,2]))
+...       g += line(desolve_rk4(DE, y, ics=[-1, i],\
+...                         step=0.05, end_points=[-2,0]))
+sage: y = var('y')
+sage: g = plot_vector_field((x, 2*y + x^3), (x,-2,2), (y,-1,1))
+sage: # g.show(ymin=-1, ymax=1)
+sage: # fin variante
+
+"""

new file sage/tests/french_book/graphique_3.py

@@ +1 @@
+r"""
+sage: import scipy; from scipy import integrate
+sage: f = lambda y, t: - cos(y * t)
+sage: t = srange(0, 5, 0.1); p = Graphics()
+sage: for k in srange(0, 10, 0.15):
+...      y = integrate.odeint(f, k, t)
+...      p += line(zip(t, flatten(y)))
+sage: t = srange(0, -5, -0.1); q = Graphics()
+sage: for k in srange(0, 10, 0.15):
+...      y = integrate.odeint(f, k, t)
+...      q += line(zip(t, flatten(y)))
+sage: y = var('y')
+sage: v = plot_vector_field((1, -cos(x * y)), (x,-5,5), (y,-2,11))
+sage: g = p + q + v; # g.show()
+sage: import scipy; from scipy import integrate
+sage: a, b, c, d = 1., 0.1, 1.5, 0.75
+sage: def dX_dt(X, t=0):
+...    return [ a*X[0] -   b*X[0]*X[1] ,
+...            -c*X[1] + d*b*X[0]*X[1] ]
+sage: t = srange(0, 15, .01)                     # echelle de temps
+sage: X0 = [10, 5]  # conditions initiales : 10 lapins et 5 renards
+sage: X = integrate.odeint(dX_dt, X0, t)     # resolution numerique
+sage: lapins, renards =  X.T         # raccourcis de  X.transpose()
+sage: p = line(zip(t, lapins), color='red') # trace du nb de lapins
+sage: p += text("Lapins",(12,37), fontsize=10, color='red')
+sage: p += line(zip(t, renards), color='blue')# idem pr les renards
+sage: p += text("Renards",(12,7), fontsize=10, color='blue')
+sage: p.axes_labels(["temps", "population"]); # p.show(gridlines=True)
+sage: ### Deuxieme graphique :
+sage: n = 11;  L = srange(6, 18, 12 / n); R=srange(3, 9, 6 / n)
+sage: CI = zip(L, R)                # liste des conditions initiales
+sage: def g(x,y):
+...       v = vector(dX_dt([x, y]))  # pour un trace plus lisible,
+...       return v/v.norm()          # on norme le champ de vecteurs
+sage: x, y = var('x, y')
+sage: q = plot_vector_field(g(x, y), (x, 0, 60), (y, 0, 36))
+sage: for j in range(n):
+...       X = integrate.odeint(dX_dt, CI[j], t)        # resolution
+...       q += line(X, color=hue(.8-float(j)/(1.8*n))) #  graphique
+sage: q.axes_labels(["lapins","renards"]); # q.show()
+sage: x, y, t = var('x, y, t')
+sage: alpha(t) = 1; beta(t) = t/2; gamma(t) = t + t**3/8
+sage: env = solve([alpha(t)*x+beta(t)*y==gamma(t),\
+...         diff(alpha(t),t)*x+diff(beta(t),t)*y==diff(gamma(t),t)],\
+...         [x,y])
+sage: f = lambda x:x^2 / 4
+sage: p = plot(f, -8, 8, rgbcolor=(0.2,0.2,0.4)) # trace la parabole
+sage: for u in srange(0, 8, 0.1): # trace des normales a la parabole
+...       p += line([[u, f(u)], [-8*u, f(u) + 18]], thickness=.3)
+...       p += line([[-u, f(u)], [8*u, f(u) + 18]], thickness=.3)
+sage: p += parametric_plot((env[0][0].rhs(),env[0][1].rhs()),\
+...       (t, -8, 8),color='red')              # trace la developpee
+sage: # p.show(xmin=-8, xmax=8, ymin=-1, ymax=12, aspect_ratio=1)
+sage: t = var('t'); p = 2
+sage: x(t) = t; y(t) = t^2 / (2 * p)
+sage: f(t) = [x(t), y(t)]
+sage: df(t) = [x(t).diff(t), y(t).diff(t)]
+sage: d2f(t) = [x(t).diff(t, 2), y(t).diff(t, 2)]
+sage: T(t) = [df(t)[0] / df(t).norm(), df[1](t) / df(t).norm()]
+sage: N(t) = [-df(t)[1] / df(t).norm(), df[0](t) / df(t).norm()]
+sage: R(t) =  (df(t).norm())^3 / \
+...        (df(t)[0] * d2f(t)[1] -df(t)[1] * d2f(t)[0])
+sage: Omega(t) = [f(t)[0] + R(t)*N(t)[0], f(t)[1] + R(t)*N(t)[1]]
+sage: g = parametric_plot(f(t), (t, -8, 8), color='green', thickness=2)
+sage: for u in srange(.4, 4, .2):
+...    g += line([f(t = u), Omega(t = u)], color='red', alpha = .5)
+...    g += circle(Omega(t = u), R(t = u), color='blue')
+sage: # g.show(aspect_ratio=1, xmin=-12, xmax=7, ymin=-3, ymax=12)
+sage: u, v = var('u, v')
+sage: h = lambda u,v: u^2 + 2*v^2
+sage: f = plot3d(h, (u,-1,1), (v,-1,1), aspect_ratio=[1,1,1])
+sage: f(x, y) = x^2 * y / (x^4 + y^2)
+sage: t, theta = var('t theta')
+sage: limit(f(t * cos(theta), t * sin(theta)) / t, t=0)
+cos(theta)^2/sin(theta)
+sage: solve(f(x,y) == 1/2, y)
+[y == x^2]
+sage: a = var('a'); h = f(x, a*x^2).simplify_rational(); h
+a/(a^2 + 1)
+sage: g = plot(h, a, -4, 4)
+sage: p = plot3d(f(x, y), (x,-2,2), (y,-2,2), plot_points=[150,150])
+sage: for i in range(1,4):
+...    p += plot3d(-0.5 + i / 4, (x, -2, 2), (y, -2, 2),\
+...                 color=hue(i / 10), opacity=.1)
+sage: x, y, z = var('x, y, z'); a = 1
+sage: h = lambda x, y, z:(a^2 + x^2 + y^2)^2 - 4*a^2*x^2-z^4
+sage: f = implicit_plot3d(h, (x, -3, 3), (y, -3, 3), (z, -2, 2),\
+...                    plot_points=100, adaptative=True)
+sage: g1 = line3d([(-10*cos(t)-2*cos(5*t)+15*sin(2*t),\
+...     -15*cos(2*t)+10*sin(t)-2*sin(5*t),\
+...      10*cos(3*t)) for t in srange(0,6.4,.1)],radius=.5)
+
+"""

new file sage/tests/french_book/sol_calculus.py

@@ +1 @@
+r"""
+sage: var('n k'); p = 4; s = [n + 1]
+(n, k)
+sage: for k in (1..p):
+...     s = s + [factor((((n + 1)^(k + 1) - sum(binomial(k + 1, j)*s[j]
+...              for j in (0..k - 1))) / (k + 1)))]
+sage: s
+[n + 1, 1/2*(n + 1)*n, 1/6*(n + 1)*(2*n + 1)*n, 1/4*(n + 1)^2*n^2, 1/30*(n + 1)*(2*n + 1)*(3*n^2 + 3*n - 1)*n]
+sage: var('x h a'); f = function('f', x)
+(x, h, a)
+sage: g(x) = taylor(f, x, a, 3)
+sage: phi(h) = (g(a+3*h)-3*g(a+2*h)+3*g(a+h)-g(a))/h**3
+sage: phi(h).expand()
+D[0, 0, 0](f)(a)
+sage: n = 7; var('x h a'); f = function('f', x)
+(x, h, a)
+sage: g(x) = taylor(f, x, a, n)
+sage: phi(h) = sum(binomial(n,k)*(-1)^(n-k)*g(a+k*h) for k in (0..n))/h**n
+sage: phi(h).expand()
+D[0, 0, 0, 0, 0, 0, 0](f)(a)
+sage: theta = 12 * arctan(1/38) + 20 * arctan(1/57) + 7 * arctan(1/239) + 24 * arctan(1/268)
+sage: x = tan(theta)
+sage: y = x.trig_expand()
+sage: y.trig_simplify()
+1
+sage: M = 12*(1/38)+20*(1/57)+ 7*(1/239)+24*(1/268)
+sage: M
+37735/48039
+sage: x = var('x')
+sage: f(x) = taylor(arctan(x), x, 0, 21)
+sage: approx = 4 * (12 * f(1/38) + 20 * f(1/57) + 7 * f(1/239) + 24 * f(1/268))
+sage: approx.n(digits = 50); pi.n(digits = 50)
+3.1415926535897932384626433832795028851616168852864
+3.1415926535897932384626433832795028841971693993751
+sage: approx.n(digits = 50) - pi.n(digits = 50)
+9.6444748591132486785420917537404705292978817080880e-37
+sage: n = var('n'); phi = lambda x: n*pi +pi/2 - arctan(1/x); x = pi * n
+sage: for i in range(4): x = taylor(phi(x), n, oo, 2 * i); x
+1/2*pi + pi*n
+1/2*pi + pi*n - 1/(pi*n) + 1/2/(pi*n^2)
+1/2*pi + pi*n - 1/(pi*n) + 1/2/(pi*n^2) - 1/12*(3*pi^2 + 8)/(pi^3*n^3) + 1/8*(pi^2 + 8)/(pi^3*n^4)
+1/2*pi + pi*n - 1/(pi*n) + 1/2/(pi*n^2) - 1/12*(3*pi^2 + 8)/(pi^3*n^3) + 1/8*(pi^2 + 8)/(pi^3*n^4) - 1/240*(15*pi^4 + 240*pi^2 + 208)/(pi^5*n^5) + 1/96*(3*pi^4 + 80*pi^2 + 208)/(pi^5*n^6)
+sage: f(x, y) = x * y * (x**2 - y**2) / (x**2 + y**2)
+sage: D1f(x, y) = diff(f(x,y), x)
+sage: limit((D1f(0,h) - 0) / h, h=0)
+-1
+sage: D2f(x, y) = diff(f(x,y), y)
+sage: limit((D2f(h,0) - 0) / h, h=0)
+1
+sage: g = plot3d(f(x, y), (x, -3, 3), (y, -3, 3))
+sage: n, t = var('n, t')
+sage: v(n) = (4/(8*n+1)-2/(8*n+4)-1/(8*n+5)-1/(8*n+6))*1/16^n
+sage: assume(8*n+1>0)
+sage: u(n) = integrate((4*sqrt(2)-8*t^3-4*sqrt(2)*t^4-8*t^5)\
+...                     * t^(8*n), t, 0, 1/sqrt(2))
+sage: (u(n)-v(n)).simplify_full()
+0
+sage: J = integrate((4*sqrt(2)-8*t^3-4*sqrt(2)*t^4-8*t^5)\
+...                 / (1-t^8), t, 0, 1/sqrt(2))
+sage: J.simplify_full()
+pi + 2*log(sqrt(2) - 1) + 2*log(sqrt(2) + 1)
+sage: ln(exp(J).simplify_log())
+pi
+sage: l = sum(v(n) for n in (0..40)); l.n(digits=60); pi.n(digits=60)
+3.14159265358979323846264338327950288419716939937510581474759
+3.14159265358979323846264338327950288419716939937510582097494
+sage: print "%e" % (l-pi).n(digits=60)
+-6.227358e-54
+sage: var('X'); ps = lambda f,g : integral(f * g, X, -pi, pi)
+X
+sage: n = 5; Q = sin(X)
+sage: var('a a0 a1 a2 a3 a4 a5'); a= [a0, a1, a2, a3, a4, a5]
+(a, a0, a1, a2, a3, a4, a5)
+sage: P = sum(a[k] * X^k for k in (0..n))
+sage: equ = [ps(P - Q, X^k) for k in (0..n)]
+sage: sol = solve(equ, a)
+sage: P = sum(sol[0][k].rhs() * X^k for k in (0..n))
+sage: g = plot(P,X,-4,4,color='red') + plot(Q,X,-4,4,color='blue')
+sage: var('p e theta1 theta2 theta3')
+(p, e, theta1, theta2, theta3)
+sage: r(theta) = p / (1-e * cos(theta))
+sage: r1 = r(theta1); r2 = r(theta2); r3 = r(theta3)
+sage: R1 = vector([r1 * cos(theta1), r1 * sin(theta1), 0])
+sage: R2 = vector([r2 * cos(theta2), r2 * sin(theta2), 0])
+sage: R3 = vector([r3 * cos(theta3), r3 * sin(theta3), 0])
+sage: D = R1.cross_product(R2) + R2.cross_product(R3) + R3.cross_product(R1)
+sage: i = vector([1, 0, 0])
+sage: S = (r1 - r3) * R2 + (r3 - r2) * R1 +   (r2 - r1) * R3
+sage: V =  S + e * i.cross_product(D)
+sage: map(lambda x:x.simplify_full(), V) # rep. : [0, 0, 0]
+[0, 0, 0]
+sage: map(lambda x:x.simplify_full(), S.cross_product(D))
+[(e*p^4*sin(theta1)^2*cos(theta2)^2 - 2*e*p^4*sin(theta1)*sin(theta2)*cos(theta1)*cos(theta2) + e*p^4*sin(theta2)^2*cos(theta1)^2 + (e*p^4*cos(theta1)^2 - 2*e*p^4*cos(theta1)*cos(theta2) + e*p^4*cos(theta2)^2)*sin(theta3)^2 + (e*p^4*sin(theta1)^2 - 2*e*p^4*sin(theta1)*sin(theta2) + e*p^4*sin(theta2)^2)*cos(theta3)^2 - 2*(e*p^4*sin(theta1)^2*cos(theta2) + e*p^4*sin(theta2)^2*cos(theta1) - (e*p^4*sin(theta1)*cos(theta1) + e*p^4*sin(theta1)*cos(theta2))*sin(theta2))*cos(theta3) + 2*(e*p^4*sin(theta1)*cos(theta1)*cos(theta2) - e*p^4*sin(theta1)*cos(theta2)^2 - (e*p^4*cos(theta1)^2 - e*p^4*cos(theta1)*cos(theta2))*sin(theta2) - (e*p^4*sin(theta1)*cos(theta1) - e*p^4*sin(theta1)*cos(theta2) - (e*p^4*cos(theta1) - e*p^4*cos(theta2))*sin(theta2))*cos(theta3))*sin(theta3))/(e^2*cos(theta1)^2 + (e^4*cos(theta1)^2 - 2*e^3*cos(theta1) + e^2)*cos(theta2)^2 + (e^4*cos(theta1)^2 - 2*e^3*cos(theta1) + (e^6*cos(theta1)^2 - 2*e^5*cos(theta1) + e^4)*cos(theta2)^2 - 2*(e^5*cos(theta1)^2 - 2*e^4*cos(theta1) + e^3)*cos(theta2) + e^2)*cos(theta3)^2 - 2*(e^3*cos(theta1)^2 - 2*e^2*cos(theta1) + e)*cos(theta2) - 2*(e^3*cos(theta1)^2 + (e^5*cos(theta1)^2 - 2*e^4*cos(theta1) + e^3)*cos(theta2)^2 - 2*e^2*cos(theta1) - 2*(e^4*cos(theta1)^2 - 2*e^3*cos(theta1) + e^2)*cos(theta2) + e)*cos(theta3) - 2*e*cos(theta1) + 1), 0, 0]
+sage: N = r3 * R1.cross_product(R2) + r1 * R2.cross_product(R3) + r2 * R3.cross_product(R1)
+sage: W =  p * S + e * i.cross_product(N)
+sage: print map(lambda x:x.simplify_full(), W)  # rep. : [0, 0, 0]
+[0, 0, 0]
+sage: R1=vector([0,1.,0]);R2=vector([2.,2.,0]);R3=vector([3.5,0,0])
+sage: r1 = R1.norm(); r2 = R2.norm(); r3 = R3.norm()
+sage: D = R1.cross_product(R2) + R2.cross_product(R3) + R3.cross_product(R1)
+sage: S = (r1 - r3) * R2 + (r3 - r2) * R1 + (r2 - r1) * R3
+sage: V =  S + e * i.cross_product(D)
+sage: N = r3 * R1.cross_product(R2) + r1 * R2.cross_product(R3) \
+...  + r2 * R3.cross_product(R1)
+sage: W =  p * S + e * i.cross_product(N)
+sage: e = S.norm() / D.norm()
+sage: p = N.norm() / D.norm()
+sage: a = p/(1-e^2)
+sage: c = a * e
+sage: b = sqrt(a^2 - c^2)
+sage: X = S.cross_product(D)
+sage: i = X / X.norm()
+sage: phi = atan2(i[1],i[0]) * 180 / pi.n()
+sage: print "%.3f %.3f %.3f %.3f %.3f %.3f" % (a, b, c, e, p, phi)
+2.360 1.326 1.952 0.827 0.746 17.917
+sage: A = matrix(QQ, [[2, -3, 2, -12, 33],
+...                   [ 6, 1, 26, -16, 69],
+...                   [10, -29, -18, -53, 32],
+...                   [2, 0, 8, -18, 84]])
+sage: A.right_kernel()
+Vector space of degree 5 and dimension 2 over Rational Field
+Basis matrix:
+[     1      0  -7/34   5/17   1/17]
+[     0      1  -3/34 -10/17  -2/17]
+sage: H = A.echelon_form()
+sage: A.column_space()
+Vector space of degree 4 and dimension 3 over Rational Field
+Basis matrix:
+[       1        0        0 1139/350]
+[       0        1        0    -9/50]
+[       0        0        1   -12/35]
+sage: S.<x,y,z,t>=QQ[]
+sage: C = matrix(S, 4,1,[x,y,z,t])
+sage: B = block_matrix([A,C], ncols=2)
+sage: C = B.echelon_form()
+sage: C[3,5]*350
+-1139*x + 63*y + 120*z + 350*t
+sage: K = A.kernel(); K
+Vector space of degree 4 and dimension 1 over Rational Field
+Basis matrix:
+[        1  -63/1139 -120/1139 -350/1139]
+sage: matrix(K.0).right_kernel()
+Vector space of degree 4 and dimension 3 over Rational Field
+Basis matrix:
+[       1        0        0 1139/350]
+[       0        1        0    -9/50]
+[       0        0        1   -12/35]
+sage: A = matrix(QQ, [[-2, 1, 1], [8, 1, -5], [4, 3, -3]])
+sage: C = matrix(QQ, [[1, 2, -1], [2, -1, -1], [-5, 0, 3]])
+sage: B = C.solve_left(A); B
+[ 0 -1  0]
+[ 2  3  0]
+[ 2  1  0]
+sage: C.left_kernel()
+Vector space of degree 3 and dimension 1 over Rational Field
+Basis matrix:
+[1 2 1]
+sage: var('x y z'); v = matrix([[1, 2, 1]])
+(x, y, z)
+sage: B = B+(x*v).stack(y*v).stack(z*v); B
+[      x 2*x - 1       x]
+[  y + 2 2*y + 3       y]
+[  z + 2 2*z + 1       z]
+sage: A == B*C
+True
+
+"""

new file sage/tests/french_book/sol_graphiques_1.py

@@ +1 @@
+r"""
+sage: t = var('t'); liste = [a + cos(t) for a in srange(0, 10, 0.1)]
+sage: g = polar_plot(liste, (t, 0, 2 * pi)); g.show(aspect_ratio=1)
+sage: f = lambda x: abs(x**2 - 1/4)
+sage: def liste_pts(u0, n):
+...     u = u0; liste = [[u0,0]]
+...     for k in range(n):
+...         v, u = u, f(u)
+...         liste.extend([[v,u], [u,u]])
+...     return(liste)
+sage: g = line(liste_pts(1.1, 8), rgbcolor = (.9,0,0))
+sage: g += line(liste_pts(-.4, 8), rgbcolor = (.01,0,0))
+sage: g += line(liste_pts(1.3, 3), rgbcolor = (.5,0,0))
+sage: g += plot(f, -1, 3, rgbcolor = 'blue')
+sage: g += plot(x, -1, 3, rgbcolor = 'green')
+sage: # g.show(aspect_ratio=1, ymin = -.2, ymax = 3)
+sage: x = var('x'); y = function('y',x); DE = x^2 * diff(y, x) -  y == 0
+sage: desolve(DE, [y,x])
+c*e^(-1/x)
+sage: g = plot([c*e^(-1/x) for c in srange(-8, 8, 0.4)], (x, -3, 3))
+sage: y = var('y'); g += plot_vector_field((x^2, y), (x,-3,3), (y,-5,5))
+sage: # g.show(ymin = -5, ymax = 5)
+sage: from sage.calculus.desolvers import desolve_system_rk4
+sage: f = lambda x, y:[a*x-b*x*y,-c*y+d*b*x*y]
+sage: x,y,t = var('x y t')
+sage: a, b, c, d = 1., 0.1, 1.5, 0.75
+sage: P = desolve_system_rk4(f(x,y),[x,y],
+...        ics=[0,10,5],ivar=t,end_points=15)
+sage: Ql = [ [i,j] for i,j,k in P]
+sage: p = line(Ql,color='red')
+sage: p += text("Lapins",(12,37),fontsize=10,color='red')
+sage: Qr = [ [i,k] for i,j,k in P]
+sage: p += line(Qr,color='blue')
+sage: p += text("Renards",(12,7),fontsize=10,color='blue')
+sage: p.axes_labels(["temps","population"])
+sage: # p.show(gridlines=True)
+sage: ### Deuxieme graphique
+sage: n = 10;  L = srange(6, 18, 12 / n); R = srange(3, 9, 6 / n)
+sage: def g(x,y):
+...     v = vector(f(x, y))
+...     return v/v.norm()
+...
+sage: q = plot_vector_field(g(x, y), (x, 0, 60), (y, 0, 36))
+sage: for j in range(n):
+...     P = desolve_system_rk4(f(x,y),[x,y],
+...            ics=[0,L[j],R[j]],ivar=t,end_points=15)
+...     Q = [ [j,k] for i,j,k in P]
+...     q += line(Q, color=hue(.8-j/(2*n)))
+...
+sage: q.axes_labels(["nombre de lapins","nombre de renards"])
+sage: # q.show()
+sage: import scipy; from scipy import integrate
+sage: def dX_dt(X, t=0):
+...     return [X[1], 0.5*X[1] - X[0] - X[1]**3]
+...
+sage: t = srange(0, 40, 0.01);  x0 = srange(-2, 2, 0.1)
+sage: y0 = 2.5
+sage: CI = [[i, y0] for i in x0] + [[i, -y0] for i in x0]
+sage: def g(x,y):
+...     v = vector(dX_dt([x, y]))
+...     return v/v.norm()
+...
+sage: x, y = var('x, y')
+sage: q = plot_vector_field(g(x, y), (x, -3, 3), (y, -y0, y0))
+sage: for j in xrange(len(CI)):
+...     X = integrate.odeint(dX_dt, CI[j], t)
+...     q += line(X, color=(1.7*j/(4*n),1.5*j/(4*n),1-3*j/(8*n)))
+...
+sage: X = integrate.odeint(dX_dt, [0.01,0], t)
+sage: q += line(X, color = 'red')
+sage: # q.show()
+
+"""

new file sage/tests/french_book/sol_graphiques_2.py

@@ +1 @@
+r"""
+sage: import scipy
+sage: from scipy import integrate
+sage: # Intervalle de temps :
+sage: t = srange(0, 40, 0.01)
+sage: # Conditions initiales en cartesiennes :
+sage: n = 35
+sage: CI_cart = [[4, .2 * i] for i in range(n)]
+sage: # Conditions initiales en polaires :
+sage: CI = map(lambda x:[sqrt(x[0]**2+x[1]**2),\
+...        pi - arctan(x[1] / x[0])], CI_cart)
+sage: # Choix du parametre alpha :
+sage: alpha = [0.1, 0.5, 1, 1.25]
+sage: for i in range(len(alpha)):
+...     # Definition du syteme differentiel :
+...     def dX_dt(X, t=0):
+...         return [cos(X[1]) * (1 - 1 / X[0]^2),\
+...         -sin(X[1]) * (1 / X[0] + 1 / X[0]^3) \
+...         + 2 * alpha[i] / X[0]^2]
+...     # trace du disque :
+...     q = circle((0, 0), 1, fill=True, rgbcolor='purple')
+...     for j in range(n):
+...         # resolution du syteme autonome :
+...         X = integrate.odeint(dX_dt, CI[j], t)
+...         # passage en cartesiennes :
+...         Y = [[u[0] * cos(u[1]), u[0] * sin(u[1])] for u in X]
+...         # trace stocke dans la variable q
+...         q += line(Y, xmin = -4, xmax = 4, color='blue')
+...     # Trace final :
+...     # q.show(aspect_ratio = 1, axes = False)
+
+"""