Ticket #10983: calculus_fixed.py

r"""
sage: var ('a,x') ; y = cos(x+a)*(x+1) ; y
(a, x)
(x + 1)*cos(a + x)
sage: var ('a,x') ; y = cos(x+a)*(x+1) ; y
(a, x)
(x + 1)*cos(a + x)
sage: y.subs(a=-x) ; y.subs(x=pi/2,a=pi/3) ; y.subs(x=0.5,a=2.3)
x + 1
-1/4*(pi + 2)*sqrt(3)
-1.41333351100299
sage: y(a=-x) ; y(x=pi/2,a=pi/3) ; y(x=0.5,a=2.3)
x + 1
-1/4*(pi + 2)*sqrt(3)
-1.41333351100299
sage: var('x,y,z') ; q = x*y+y*z+z*x
(x, y, z)
sage: bool (q(x=y,y=z,z=x)==q), bool(q(z=y)(y=x) == 3*x^2)
(True, True)
"""

r"""
sage: var('y z'); f = x^3+y^2+z; f.subs_expr(x^3==y^2, z==1)
(y, z)
2*y^2 + 1
sage: f(x)=(2*x+1)^3 ; f(-3)
  -125
sage: f(x).expand()
8*x^3 + 12*x^2 + 6*x + 1
sage: var('y'); u = sin(x) + x*cos(y)
y
sage: v = u.function(x, y); v
(x, y) |--> x*cos(y) + sin(x)
sage: w(x, y) = u; w
(x, y) |--> x*cos(y) + sin(x)
"""

r"""
sage: (x^x/x).simplify()
x^(x - 1)
sage: f = (e^x-1)/(1+e^(x/2)); f.simplify_exp()
e^(1/2*x) - 1
sage: f = cos(x)^6 + sin(x)^6 + 3 * sin(x)^2 * cos(x)^2
sage: f.simplify_trig()
1
sage: f = cos(x)^6; f.reduce_trig()
15/32*cos(2*x) + 3/16*cos(4*x) + 1/32*cos(6*x) + 5/16
sage: f = sin(5 * x); f.expand_trig()
sin(x)^5 - 10*sin(x)^3*cos(x)^2 + 5*sin(x)*cos(x)^4
sage: n = var('n'); f = factorial(n+1)/factorial(n)
sage: f.simplify_factorial()
n + 1
"""

r"""
sage: reset()
sage: f = sqrt(x^2); f.simplify_radical()
abs(x)
sage: var('y')
y
sage: f = log(x*y); f.simplify_radical()
log(x) + log(y)
sage: assume(x > 0); bool(sqrt(x^2) == x)
True
sage: forget(x > 0); bool(sqrt(x^2) == x)
False
sage: var('n'); assume(n, 'integer'); sin(n*pi).simplify()
n
0
"""

r"""
sage: z, phi = var('z, phi')
sage: solve(z**2 -2 / cos(phi) * z + 5 / cos(phi) ** 2 - 4, z)
[z == -(2*sqrt(cos(phi)^2 - 1) - 1)/cos(phi), z == (2*sqrt(cos(phi)^2 - 1) + 1)/cos(phi)]
sage: var('y'); solve(y^6==y, y)
y
[y == e^(2/5*I*pi), y == e^(4/5*I*pi), y == e^(-4/5*I*pi), y == e^(-2/5*I*pi), y == 1, y == 0]
sage: solve(x^2-1, x, solution_dict=True)
[{x: -1}, {x: 1}]
sage: solve([x+y == 3, 2*x+2*y == 6],x,y)
[[x == -r1 + 3, y == r1]]
sage: solve([cos(x)*sin(x) == 1/2, x+y == 0], x, y)
[[x == 1/4*pi + pi*z30, y == -1/4*pi - pi*z30]]
sage: solve(x^2+x-1>0,x)
[[x < -1/2*sqrt(5) - 1/2], [x > 1/2*sqrt(5) - 1/2]]
"""

r"""
sage: x, y, z = var('x, y, z')
sage: solve([x^2 * y * z == 18, x * y^3 * z == 24,\
             x * y * z^4 == 6], x, y, z)
[[x == 3, y == 2, z == 1], [x == (1.33721506733 - 2.68548987407*I), y == (-1.70043427146 + 1.05286432575*I), z == (0.932472229404 - 0.361241666187*I)], [x == (1.33721506733 + 2.68548987407*I), y == (-1.70043427146 - 1.05286432575*I), z == (0.932472229404 + 0.361241666187*I)], [x == (-2.55065140719 - 1.57929648863*I), y == (-0.547325980144 + 1.92365128635*I), z == (-0.982973099684 - 0.183749517817*I)], [x == (-2.55065140719 + 1.57929648863*I), y == (-0.547325980144 - 1.92365128635*I), z == (-0.982973099684 + 0.183749517817*I)], [x == (0.27680507839 - 2.98720252889*I), y == (1.47801783444 - 1.34739128729*I), z == (-0.85021713573 - 0.526432162877*I)], [x == (0.27680507839 + 2.98720252889*I), y == (1.47801783444 + 1.34739128729*I), z == (-0.85021713573 + 0.526432162877*I)], [x == (-0.820988970216 + 2.88547692952*I), y == (-1.20526927276 - 1.59603445456*I), z == (0.0922683594633 - 0.995734176295*I)], [x == (-0.820988970216 - 2.88547692952*I), y == (-1.20526927276 + 1.59603445456*I), z == (0.0922683594633 + 0.995734176295*I)], [x == (-1.80790390914 - 2.39405168184*I), y == (0.891476711553 - 1.79032658271*I), z == (0.739008917221 - 0.673695643647*I)], [x == (-1.80790390914 + 2.39405168184*I), y == (0.891476711553 + 1.79032658271*I), z == (0.739008917221 + 0.673695643647*I)], [x == (2.21702675166 + 2.02108693094*I), y == (1.86494445881 + 0.722483332374*I), z == (-0.273662990072 - 0.961825643173*I)], [x == (2.21702675166 - 2.02108693094*I), y == (1.86494445881 - 0.722483332374*I), z == (-0.273662990072 + 0.961825643173*I)], [x == (2.79741668821 - 1.08372499856*I), y == (-1.96594619937 + 0.367499035633*I), z == (-0.602634636379 - 0.79801722728*I)], [x == (2.79741668821 + 1.08372499856*I), y == (-1.96594619937 - 0.367499035633*I), z == (-0.602634636379 + 0.79801722728*I)], [x == (-2.94891929905 + 0.55124855345*I), y == (0.184536718927 + 1.99146835259*I), z == (0.445738355777 - 0.895163291355*I)], [x == (-2.94891929905 - 0.55124855345*I), y == (0.184536718927 - 1.99146835259*I), z == (0.445738355777 + 0.895163291355*I)]]
"""

r"""
sage: expr = sin(x) + sin(2 * x) + sin(3 * x)
sage: solve(expr, x)
[sin(3*x) == -sin(2*x) - sin(x)]
sage: find_root(expr, 0.1, pi)
2.0943951023931957
sage: f = expr.simplify_trig(); f
2*(2*cos(x)^2 + cos(x))*sin(x)
sage: solve(f, x)
[x == 0, x == 2/3*pi, x == 1/2*pi]
sage: (x^3+2*x+1).roots(x)
[(-1/2*(I*sqrt(3) + 1)*(1/18*sqrt(3)*sqrt(59) - 1/2)^(1/3) - 1/3*(I*sqrt(3) - 1)/(1/18*sqrt(3)*sqrt(59) - 1/2)^(1/3), 1), (-1/2*(-I*sqrt(3) + 1)*(1/18*sqrt(3)*sqrt(59) - 1/2)^(1/3) - 1/3*(-I*sqrt(3) - 1)/(1/18*sqrt(3)*sqrt(59) - 1/2)^(1/3), 1), ((1/18*sqrt(3)*sqrt(59) - 1/2)^(1/3) - 2/3/(1/18*sqrt(3)*sqrt(59) - 1/2)^(1/3), 1)]
sage: (x^3+2*x+1).roots(x, ring=RR)
 [(-0.453397651516404, 1)]
sage: (x^3+2*x+1).roots(x, ring=CC)
 [(-0.453397651516404, 1), (0.226698825758202 - 1.46771150871022*I, 1), (0.226698825758202 + 1.46771150871022*I, 1)]
"""

r"""
sage: var('k n'); sum(k, k, 1, n).factor()
 (k, n)
 1/2*(n + 1)*n
sage: var('n y'); sum(binomial(n,k) * x^k * y^(n-k), k, 0, n)
 (n, y)
 (x + y)^n
sage: var('k n'); sum(binomial(n,k), k, 0, n),\
                  sum(k * binomial(n, k), k, 0, n),\
                  sum((-1)^k*binomial(n,k), k, 0, n)
(k, n)
(2^n, n*2^(n - 1), 0)
sage: var('a q'); sum(a*q^k, k, 0, n)
(a, q)
(a*q^(n + 1) - a)/(q - 1)
sage: assume(abs(q) < 1)
sage: sum(a*q^k, k, 0, infinity)
 -a/(q - 1)
"""

r"""
sage: limit((x**(1/3) -2) / ((x + 19)**(1/3) - 3), x = 8)
9/4
sage: f(x) = (cos(pi/4-x)-tan(x))/(1-sin(pi/4 + x))
sage: limit(f(x), x = pi/4, dir='minus')
+Infinity
sage: limit(f(x), x = pi/4, dir='plus')
-Infinity
sage: u(n) = n^100 / 100.^n
sage: u(1);u(2);u(3);u(4);u(5);u(6);u(7);u(8);u(9);u(10)
0.0100000000000000
1.26765060022823e26
5.15377520732011e41
1.60693804425899e52
7.88860905221012e59
6.53318623500071e65
3.23447650962476e70
2.03703597633449e74
2.65613988875875e77
1.00000000000000e80
sage: plot(u(x), x, 1, 40)
sage: v(x) = diff(u(x), x); sol = solve(v(x) == 0, x); sol
[x == 0, x == (268850/12381)]
sage: sol[1].rhs().n().floor()
21
sage: limit(u(n), n=infinity)
0
sage: n0 = find_root(u(n) - 1e-8 == 0, 22, 1000); n0
105.07496210187252
"""

r"""
sage: taylor((1+arctan(x))**(1/x), x, 0, 3)
1/16*x^3*e + 1/8*x^2*e - 1/2*x*e + e
sage: (ln(2* sin(x))).series(x==pi/6, 3)
(sqrt(3))*(-1/6*pi + x) + (-2)*(-1/6*pi + x)^2 + Order(-1/216*(pi - 6*x)^3)
sage: (ln(2* sin(x))).series(x==pi/6, 3).truncate()
-1/18*(pi - 6*x)^2 - 1/6*(pi - 6*x)*sqrt(3)
sage: taylor((x**3+x)**(1/3) - (x**3-x)**(1/3), x, infinity, 2)
2/3/x
sage: tan(4*arctan(1/5)).simplify_trig()
120/119
sage: tan(pi/4+arctan(1/239)).simplify_trig()
120/119
sage: f = arctan(x).series(x, 10); f
1*x + (-1/3)*x^3 + 1/5*x^5 + (-1/7)*x^7 + 1/9*x^9 + Order(x^10)
sage: (16*f.subs(x==1/5) - 4*f.subs(x==1/239)).n(); pi.n()
3.14159268240440
3.14159265358979
"""

r"""
sage: var('k'); sum(1/k^2, k, 1, infinity),\
                sum(1/k^4, k, 1, infinity),\
                sum(1/k^5, k, 1, infinity)
k
(1/6*pi^2, 1/90*pi^4, zeta(5))
sage: s = 2*sqrt(2)/9801*(sum((factorial(4*k))*(1103+26390*k)\
     /((factorial(k)) ^ 4 * 396 ^ (4 * k)) for k in (0..11)))
sage: (1 / s).n(digits=100); pi.n(digits=100)
3.141592653589793238462643383279502884197169399375105820974944592307816406286208998628034825342121432
3.141592653589793238462643383279502884197169399375105820974944592307816406286208998628034825342117068
sage: print "%e" % (pi - 1 / s).n(digits=100)
-4.364154e-96
sage: var('n'); u = sin(pi*(sqrt(4*n^2+1)-2*n))
n
sage: taylor(u, n, infinity, 3)
1/4*pi/n - 1/384*(6*pi + pi^3)/n^3
sage: diff(sin(x^2), x)
2*x*cos(x^2)
"""

r"""
sage: function('f',x); function('g',x); diff(f(g(x)), x)
f(x)
g(x)
D[0](f)(g(x))*D[0](g)(x)
sage: diff(ln(f(x)), x)
D[0](f)(x)/f(x)
sage: f(x,y) = x*y + sin(x^2) + e^(-x); derivative(f, x)
(x, y) |--> 2*x*cos(x^2) + y - e^(-x)
sage: derivative(f, y)
(x, y) |--> x
sage: var('x y'); f = ln(x**2+y**2) / 2
(x, y)
sage: delta = diff(f,x,2)+diff(f,y,2)
sage: delta.simplify_full()
0
sage: sin(x).integral(x, 0, pi/2)
1
sage: integrate(1/(1+x^2), x)
arctan(x)
sage: integrate(1/(1+x^2), x, -infinity, infinity)
pi
sage: integrate(exp(-x**2), x, 0, infinity)
1/2*sqrt(pi)
sage: u = var('u'); f = x * cos(u) / (u^2 + x^2)
sage: assume(x>0); f.integrate(u, 0, infinity)
1/2*pi*e^(-x)
sage: forget(); assume(x<0); f.integrate(u, 0, infinity)
-1/2*pi*e^x
sage: integral_numerical(sin(x)/x, 0, 1)
(0.946083070367182..., 1.050363207929708...e-14)
sage: g = integrate(exp(-x**2), x, 0, infinity); g, g.n()
(1/2*sqrt(pi), 0.886226925452...)
sage: approx = integral_numerical(exp(-x**2), 0, infinity)
sage: approx[0]
0.88622692545275...
"""

r"""
sage: A = matrix(QQ,[[1,2],[3,4]]); A
[1 2]
[3 4]
sage: A = matrix(QQ, [[2, 4, 3],[-4,-6,-3],[3,3,1]])
sage: A.characteristic_polynomial()
x^3 + 3*x^2 - 4
sage: A.eigenvalues()
[1, -2, -2]
sage: A.minimal_polynomial().factor()
(x - 1) * (x + 2)^2
sage: A.eigenvectors_right()
[(1, [
(1, -1, 1)
], 1), (-2, [
(1, -1, 0)
], 2)]
sage: A.jordan_form(transformation=True)
(
[ 1| 0  0]
[--+-----]  [ 1  1  1]
[ 0|-2  1]  [-1 -1  0]
[ 0| 0 -2], [ 1  0 -1]
)
"""

r"""
sage: A = matrix(QQ, [[1,-1/2],[-1/2,-1]])
sage: A.minimal_polynomial()
x^2 - 5/4
sage: R = QQ[sqrt(5)]
sage: A = A.change_ring(R)
sage: A.jordan_form(transformation=True, subdivide=False)
(
[ 1/2*sqrt5          0]  [         1          1]
[         0 -1/2*sqrt5], [-sqrt5 + 2  sqrt5 + 2]
)
sage: K.<sqrt2> = NumberField(x^2 - 2)
sage: L.<sqrt3> = K.extension(x^2 - 3)
sage: A = matrix(L, [[2, sqrt2*sqrt3, sqrt2], [sqrt2*sqrt3, 3, sqrt3], [sqrt2, sqrt3, 1]])
sage: A.jordan_form(transformation=True)
(
[6|0|0]
[-+-+-]
[0|0|0]  [              1               1               0]
[-+-+-]  [1/2*sqrt2*sqrt3               0               1]
[0|0|0], [      1/2*sqrt2          -sqrt2          -sqrt3]
)
"""